云烟过眼录

 rem 这个哥们很强大，用 cmd 脚本写了个 ARP 绑定的工具，很多技巧可以借鉴，收藏一下。

cls
@echo off

rem 自动绑定192.168.1.x 这个网段的ARP
rem 本脚本在xp下测试通过

rem local_net_ip 是你所在的网络，可以根据你的实际情况做相应的更改

set local_net_ip=192.168.1
rem 保存配置的文件
set arp_ini=c:\arp.ini
title ARP自动绑定脚本 v1.0 作者comsyschen@163.com
echo ARP自动绑定脚本 v1.0 作者comsyschen@163.com
echo ===============================================
echo 本程序将扫描%local_net_ip%.255这个网段
echo 如果你的PC不是这个网段的IP,请终止本程序
echo 并修改set local_net_ip=192.168.1语句为你实际的IP网段
echo ===============================================
pause
rem 如果文件存在，就执行绑定
rem 如果要重新扫描，请删除%arp_ini%文件，或者改变%arp_ini%文件
if exist %arp_ini% goto ARPBIND

for /l %%a in (1,1,254) do (
cls
echo 正在搜索ARP对应关系 %%a/255，请稍后 当前正在处理%local_net_ip%.%%a
arp -d
ping -w 50 -n 1 %local_net_ip%.%%a > 1.tmp
arp -a |find "dynamic">>%arp_ini%
)

echo ARP搜索完毕

:ARPBIND
echo 正在进行ARP绑定
for /F "tokens=1-2" %%a in (%arp_ini%) do (
echo %%a %%b
arp -s %%a %%b
)

echo ARP绑定完成
echo 请执行arp -a 检查是否正确
echo 如果要在其它PC上执行ARP绑定，请把本脚本和%arp_ini%，拷贝到其他PC上，运行即可
echo ============================================================================

:Select
echo 是否要每次开机自动绑定
echo yes 谢谢，请帮我自动绑定
echo no 不用了，谢谢
set /p a="yes|no:"
if /i %a% EQU yes (
echo @echo off >staticarp.bat
echo echo 正在进行ARP绑定 >>staticarp.bat
for /F "tokens=1-2" %%a in (%arp_ini%) do echo arp -s %%a %%b >>staticarp.bat
echo echo ARP 绑定完毕，请执行命令arp -a 检查 >>staticarp.bat
echo pause >>staticarp.bat
copy staticarp.bat "C:\Documents and Settings\username\「开始」菜单\程序\启动\staticarp.bat" /y
echo 以后每次开启PC，都会自动执行ARP绑定脚本

goto MEND
)

if /i %a% EQU no goto MEND

cls
goto Select

:MEND

更多有趣日志